tts_volume

Indicates the sound level. Wavelink recommends using the calibration tool to adjust this setting, rather than setting it through a script or the screen reformatter.

Possible Values

Any number from 0 to 100, with the default being the value last set in the calibration tool. For devices that support "boost" (a hardware amplifier that can be enabled or disabled), values of 51-100 will be boosted, while 0-50 will not. For devices that don't support boost, the range of 0-100 will just be softest to loudest.

Example #1

This script is designed to be triggered by a speech-to-text global action to increase the volume. The word "louder" could be added to a grammar file to act as a command that calls the following script.

Script( IncreaseVolume )
String( sVolume )
String( sMessage )
Number( nVolume )
Number( nVolumeCalc )
Comment: Increase Volume by 10%
nVolume = Speech_Get_Setting( "tts_volume" )
nVolumeCalc = Number_Multiply( nVolume, 11 )
nVolume = Number_Divide( nVolumeCalc, 10 )
If( Number_Greater_Than_Or_Equal( nVolume, 100 ) )
Speech_From_Text( "Volume already at maximum.", TRUE )
Message( "Volume already at maximum.", 5 )
Speech_Change_Setting( "tts_volume", 100 )
Else
Speech_Change_Setting( "tts_volume", nVolume )
sVolume = Number_To_String_Decimal( nVolume )
sMessage = "New Volume Level is: "
sMessage = String_Combine( sMessage, sVolume )
Message( sMessage, 5 )
End_If
Return

Example #2

This script is designed to be triggered by a speech-to-text global action to decrease the volume. The term "softer" could be added to a grammar file to act as a command that calls the following script.

Script( DecreaseVolume )
String( sVolume )
String( sMessage )
Number( nVolume )
Number( nVolumeCalc )
Comment: Decrease Volume by 10%
nVolume = Speech_Get_Setting( "tts_volume" )
nVolumeCalc = Number_Multiply( nVolume, 9 )
nVolume = Number_Divide( nVolumeCalc, 10 )
If( Number_Less_Than_Or_Equal( nVolume, 10 ) )
Speech_From_Text( "Volume already at minimum.", TRUE )
Message( "Volume already at minimum.", 5 )
Speech_Change_Setting( "tts_volume", 10 )
Else
Speech_Change_Setting( "tts_volume", nVolume )
sVolume = Number_To_String_Decimal( nVolume )
sMessage = "New Volume Level is: "
sMessage = String_Combine( sMessage, sVolume )
Message( sMessage, 5 )
End_If
Return

Example #3

Script( Speech_From_Text_Volume )
String( strDescription )
String( strSetting )
String( strMessage )
String( strPrompt )
Boolean( bResult )
Number( nVolume )
Number( nSettingMax )
Activate( From_Menu )
If_Not( Speech_From_Text_Available )
Message( "Speech From Text Not Available", 3 )
Return
End_If

strSetting = "tts_volume"
nVolume = Speech_Get_Setting( strSetting )
strDescription = Speech_Get_Setting_Value_Desc(strSetting, nVolume)

strMessage = String_Combine( "Volume: ", strDescription )
strMessage = String_Combine( strMessage, "; setting value: " )
strMessage = String_Combine( strMessage, Number_To_String_Decimal( nVolume ) )
Speech_From_Text( strMessage, FALSE )
nSettingMax = Speech_Get_Setting_Max( strSetting )
strPrompt = String_Combine( "From 0 to ", Number_To_String_Decimal( nSettingMax ) )
While( Number_Not_Equal( nVolume, 0 ) )
nVolume = Ask_Number( strPrompt, "New volume, 0 to exit", 0, nSettingMax, nVolume )
If( Number_Not_Equal( nVolume, 0 ) )
bResult = Speech_Change_Setting( strSetting, nVolume )
If( bResult )
strMessage = String_Combine( "The new volume level is ", Number_To_String_Decimal( nVolume ) )
Speech_From_Text( strMessage, FALSE )
Else
Message( "Setting volume failed", 3 )
nVolume = 0
End_If
End_If
End_While
Return

See Also

stt_volume, Speech_Get_Setting, Speech_Get_Setting_Value_Desc, Speech_Get_Setting_Max, Speech_Find_Setting_Value, Speech_To_Text, Speech_From_Text, Speech_Setting_Available, Speech_Change_Setting